Trong Excel, hàm VLOOKUP dùng để tra cứu dữ liệu và hàm IF dùng để kiểm tra điều kiện và trả về kết quả khác nhau khi đúng hoặc sai điều kiện. Ta có thể kết hợp 2 hàm VLOOKUP và IF để xử lý các trường hợp như:
- Hiển thị thông báo “Không tìm thấy” nếu không tìm thấy dữ liệu khi tra cứu/
- So sánh hai bảng và đánh dấu các giá trị trùng/khác.
- Tra cứu dữ liệu có điều kiện (ví dụ chỉ tra trong nhóm sản phẩm hoặc khu vực cụ thể).
Dưới đây, mình sẽ hướng dẫn cách để kết hợp hàm VLOOKUP và hàm IF với các tình huống thực tế.
1. Cấu trúc và nguyên lý kết hợp hàm IF và VLOOKUP
Khi kết hợp hàm VLOOKUP và hàm IF ta sẽ bọc hàm IF bên ngoài hàm VLOOKUP. Trong đó cú pháp cơ bản hàm:
- Hàm IF:
=IF(logical_test, value_if_true, value_if_false) - Hàm VLOOKUP:
=VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup])
Khi lồng hàm VLOOKUP ta có thể sử dụng hàm VLOOKUP để thay thế các tham số logic_test, value_if_true, hoặc value_if_false trong hàm IF:
- Sử dụng VLOOKUP thay thế
logical_test- Mục đích: để tra cứu để kiểm tra một điều kiện, từ đó đưa ra kết luận đúng/sai.
- Ví dụ: Nếu giá trong bảng tra lớn hơn 1 triệu → Ghi ‘Giá cao’, ngược lại ghi ‘Giá thấp’”.
- Công thức:
=IF(VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup]), value_if_true, value_if_false)
- Sử dụng VLOOKUP thay thế
value_if_true:- Mục đích: dùng để chỉ tra cứu dữ liệu khi điều kiện đúng, còn nếu không thì trả về giá trị khác.
- Ví dụ: Chỉ tra cứu giá nếu sản phẩm thuộc nhóm Điện tử.
- Công thức:
=IF(logical_test, VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup]), value_if_false)
- Sử dụng VLOOKUP thay thế
value_if_false- Mục đích: Thực hiện tra cứu khác khi điều kiện sai, tức là IF điều hướng VLOOKUP đến bảng khác hoặc kiểu tra khác.
- Công thức:
=IF(logical_test, value_if_true, VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup]))
Khi nắm được bản chất cách kết hợp hàm VLOOKUP và hàm IF ta có thể dễ dàng ghi nhớ công thức và thực hiện các yêu cầu khi làm việc dễ dàng.
2. Cách kết hợp hàm VLOOKUP với hàm IF trong một số trường hợp phổ biến
Để hiểu rõ cách kết hợp hàm VLOOKUP và hàm IF, hãy cùng tìm hiểu trực tiếp các trường hợp kết hợp phổ biến nhất dưới đây:
TH1: Tránh lỗi #N/A khi không tìm thấy dữ liệu trong VLOOKUP
Hàm VLOOKUP khi không tìm thấy dữ liệu trong bảng tra cứu sẽ trả về lỗi #N/A. Ta có thể sử dụng hàm IF để bọc ngoài và tạo thông báo như “không tìm thấy” với công thức chung như sau:
=IF(ISNA(VLOOKUP(...)), "Không tìm thấy", VLOOKUP(...))
Hoặc ta có thể sử dụng hàm IFERROR:
=IFERROR(VLOOKUP(...), "Giá trị không tồn tại")
Ví dụ minh họa:
Giả sử ta có danh sách về sản phẩm và giá bán như dưới đây. Và ta muốn tra cứu giá bán dựa trên tên sản phẩm, nếu tên có trong danh sách thì trả về giá bán tương ứng, nếu không có trong danh sách thì trả về thông báo “Không có“.
Để thực hiện ta sử dụng công thức sau:
=IFERROR(VLOOKUP(A2; $D$2:$E$7; 2; FALSE); "Không có")
Hoặc:
=IF(ISNA(VLOOKUP(A2; $D$2:$E$7; 2; FALSE)); "Không có"; VLOOKUP(A2; $D$2:$E$7; 2; FALSE))
Trong đó:
A2là giá trị tên sản phẩm cần tra cứu.D2:E7là vùng dữ liệu tên sản phẩm và giá bán.
Kết quả hàm sẽ trả về như sau:
>>> Xem thêm: Cách sử dụng hàm VLOOKUP 2 điều kiện (Ví dụ chi tiết)
TH2: Chỉ tra cứu dữ liệu khi thỏa mãn điều kiện
Khi sử dụng hàm VLOOKUP thay tế cho tham số value_if_true của hàm IF. Ta có thể đặt điều kiện để chỉ thực hiện tra cứu khi thỏa mãn điều kiện. Công thức chung như sau:
=IF(điều_kiện,VLOOKUP(...),giá_trị_sai)
Ví dụ: Ta có bảng dữ liệu về mã sản phẩm và giá bán như dưới đây. Ta muốn tra cứu dữ liệu dựa trên các sản phẩm đã bán nhưng chỉ tra cứu khi sản phẩm là loại hàng “Điện tử“:
Ta nhập công thức sau:
=IF(C2="Điện tử"; VLOOKUP(A2; $F$2:$H$11; 3; FALSE); "Không áp dụng")
=> Excel sẽ kiểm tra C2=”Điện tử” hay không? => Nếu đúng, nó sẽ tra cứu giá trị A2 trong vùng F2:H11 để trả về giá bán ở cột 3. Nếu sai, thì trả về thông báo “Không áp dụng“.
>>> Xem thêm: Hướng dẫn cách dùng hàm VLOOKUP giữa 2 Sheet trong Excel
TH3: Dùng hàm IF lồng VLOOKUP để xét nhiều điều kiện
Áp dụng khi: Ta cần xét nhiều điều kiện trước khi tra cứu (lồng nhiều hàm IF). Mỗi điều kiện sẽ dẫn tới 1 lệnh VLOOKUP tương ứng.
Công thức chung:
=IF(Điều_kiện, VLOOKUP(...), IF(Điều kiện, VLOOKUP(...),Giá_trị_sai))
Ví dụ minh họa:
Ta có bảng dữ liệu quy định mức thưởng theo cấp bậc như sau:
Giờ ta muốn tra cứu mức thưởng với yêu cầu:
- Nếu là Trưởng phòng → tra bảng thưởng trưởng phòng.
- Nếu là Nhân viên → tra bảng thưởng nhân viên.
- Nếu khác hai chức vụ trên → hiển thị “Không xác định”.
=> Ta sử dụng công thức hàm IF và VLOOKUP như sau:
=IF(B2="Trưởng phòng"; VLOOKUP(A2; $E$2:$F$4; 2; FALSE); IF(B2="Nhân viên"; VLOOKUP(A2; $H$2:$I$4; 2; FALSE); "Không xác định"))
Công thức trên, Excel sẽ:
- Tiến hành kiểm tra xem B2 là “Trưởng phòng” hay “Nhân viên“.
- Nếu đúng => Thực hiện lệnh VLOOKUP trên bảng dữ liệu tương ứng.
- Nếu sai => Trả về thông báo “Không xác định“.
>>> Xem thêm: Cách sử dụng hàm VLOOKUP trong cùng Sheet, khác Sheet và khác file
Trên đây là hướng dẫn chi tiết cách để kết hợp hàm VLOOKUP và hàm IF trong các ví dụ thực tế. Điều quan trọng là bạn nắm được nguyên tắc kết hợp của 2 hàm này. Từ đó, ta có thể vận dụng 1 cách linh hoạt. Chúc các bạn áp dụng thành công!
