Bạn muốn tính thuế thu nhập cá nhân (TNCN) trực tiếp trong Excel, tự động theo đúng quy định cho 3 trường hợp: cư trú HĐLĐ ≥ 3 tháng (lũy tiến), cư trú không HĐLĐ/<3 tháng (khấu trừ 10%), và không cư trú (20%)? Bài này hướng dẫn từ A–Z, có file mẫu để nhập liệu là ra kết quả ngay.
1. Nắm nhanh công thức tính thuế TNCN
1.1. Công thức chung:
Để hiểu rõ cách tính thuế TNCN, ta cần phải nắm rõ 3 công thức tính sau:
- Thu nhập chịu thuế (Base) = Tổng thu nhập (Gross) – Khoản miễn thuế (tăng ca/ban đêm phần chênh lệch, thu nhập thuyền viên, miễn khác…).
- Thu nhập tính thuế (TNTT) = Thu nhập chịu thuế – Giảm trừ (bản thân + người phụ thuộc + bảo hiểm, từ thiện/khuyến học/nhân đạo, quỹ hưu trí tự nguyện).
- Thuế TNCN = TNTT × Thuế suất (tuỳ trường hợp).
1.2. Ba trường hợp tính thuế TNCN:
Hiện tại, việc tính thuế TNCN được dựa trên 3 trường hợp với cách tính như sau:
- (A) Cư trú – HĐLĐ ≥ 3 tháng: áp dụng biểu lũy tiến từng phần theo tháng (5% → 35%) + số trừ nhanh.
- (B) Cư trú – Không HĐLĐ/<3 tháng: khấu trừ 10% trên tổng thu nhập từ 2 triệu/lần trở lên (trừ trường hợp đủ điều kiện cam kết).
- (C) Không cư trú: 20% trên thu nhập chịu thuế (không có giảm trừ gia cảnh).
(Lưu ý: luôn cập nhật cách tính thuế TNCN theo quy định mới nhất để đảm bảo tính chính xác khi áp dụng công thức).
2. Chuẩn bị dữ liệu để tính thuế TNCN trong Excel
Để tính thuế TNCN trong Excel, ta cần phải chuẩn bị nhập các dữ liệu đầu vào sau:
- Bảng biểu thuế lũy tiến theo tháng.
- Các dữ liệu về tổng thu nhập, tiền tăng ca, miễn trừ thu nhập, giảm trừ bản thân, số người phụ thuộc, mức giảm trừ/1 người phụ thuộc, mức tiền bảo hiểm + từ thiện + hưu trí,…
Để dễ dàng thực hiện và nhập liệu mình đã tạo sẵn 1 file mẫu dữ liệu gồm đầy đủ các thông tin để bạn nhập liệu gồm 3 sheet:
- Input: nơi nhập liệu và nhận kết quả (ô nhập được tô vàng).
- TaxBrackets: bậc thuế theo tháng + thuế suất + số trừ nhanh (phục vụ cách tính rút gọn).
- Readme: hướng dẫn chi tiết cách sử dụng File để tính thuế TNCN.
Xem ngay File tính thuế TNCN có sẵn kèm công thức
Trong bảng mẫu mình đã thiết lập dữ liệu như sau, bạn chỉ cần nhập liệu các ô màu nền vàng:
- Cột A: Họ tên
- Cột B: Kỳ YYYY-MM
- Cột C: Tổng thu nhập (Gross)
- Cột D đến F: Khoản miễn thuế (D: tăng ca/ban đêm phần chênh lệch; E: thuyền viên; F: miễn khác)
- Cột H: Giảm trừ bản thân (mặc định 11.000.000 VND/tháng)
- Cột I: Số người phụ thuộc.
- Cột J: Giảm trừ/NPT (mặc định 4.400.000 VND)
- Cột K: Bảo hiểm + từ thiện/khuyến học/nhân đạo + hưu trí tự nguyện
- Cột M: Loại lao động (chọn 1):
- HĐLĐ >=3m (cư trú).
- Không HĐLĐ/<3m (cư trú).
- Không cư trú.
3. Công thức Excel tính thuế TNCN
Dưới đây là logic và công thức (có thể tùy biến) để tính từng giá trị trong bảng dữ liệu mẫu tính thuế TNCN:
- G – Thu nhập chịu thuế (Base):
=MAX(0, C2 - SUM(D2:F2)) - L – Thu nhập tính thuế (TNTT) (áp dụng cho cư trú HĐLĐ ≥3 tháng):
=MAX(0, G2 - (H2 + I2*J2 + K2)) - N – Thuế lũy tiến (cư trú ≥3 tháng) – cách rút gọn:
=IF(L2<=0,0,
ROUND(L2*VLOOKUP(L2,TaxBrackets!$A$2:$D$8,3,TRUE)
-VLOOKUP(L2,TaxBrackets!$A$2:$D$8,4,TRUE),0)) - O – Thuế 10% (cư trú, không HĐLĐ/<3 tháng):
=ROUND(0.1*C2,0) - P – Thuế 20% (không cư trú):
=ROUND(0.2*G2,0) - Q – Thuế TNCN phải nộp (tự chọn theo Loại lao động):
=IF(M2="HĐLĐ >=3m (cư trú)", N2,IF(M2="Không HĐLĐ/<3m (cư trú)", O2,IF(M2="Không cư trú", P2, ""))) - R – Lương thực nhận (ước tính):
=C2 - Q2
4. Ví dụ minh họa
Ví dụ 1: Cư trú – HĐLĐ ≥ 3 tháng (lũy tiến):
Thông tin giả định:
- C2 – Gross: 35.000.000
- D2 – Miễn tăng ca/ban đêm (chênh lệch): 1.000.000
- E2 – Thu nhập thuyền viên: 0
- F2 – Miễn khác: 0
- H2 – Giảm trừ bản thân: 11.000.000
- I2 – Số người phụ thuộc: 1
- J2 – Giảm trừ/NPT: 4.400.000
- K2 – BH + từ thiện/khuyến học/nhân đạo + quỹ hưu trí: 2.000.000
- M2 – Loại: HĐLĐ >=3m (cư trú)
Tính:
Tính thu nhập chịu thuế với công thức ở G2:
G2 = MAX(0, C2 - SUM(D2:F2)) => Kết quả cho ra: = 35.000.000 – (1.000.000 + 0 + 0) = 34.000.000
Tính thu nhập tính thuế ở L2:
L2 = MAX(0, G2 - (H2 + I2*J2 + K2)) => kết quả cho ra: = 34.000.000 – (11.000.000 + 1*4.400.000 + 2.000.000) = 34.000.000 – 17.400.000 = 16.600.000
Tính thuế TNCN theo phương pháp rút gọn ở N2:
N2 = IF(L2<=0,0, ROUND(L2*VLOOKUP(L2,TaxBrackets!$A$2:$D$8,3,TRUE) -VLOOKUP(L2,TaxBrackets!$A$2:$D$8,4,TRUE),0))
Giải thích: L2 = 16,6 triệu rơi vào bậc >10–18 triệu, thuế suất 15%, số trừ nhanh 750.000.
=> Thuế = 16.600.000 × 15% – 750.000 = 2.490.000 – 750.000 = 1.740.000 → N2 = 1.740.000
Tính thuế phải nộp ở Q2:
vì là HĐLĐ >=3m (cư trú nên Q2 = N2 = 1.740.000.
Tính lương thực nhận:
R2 = C2 - Q2 => kết quả: = 35.000.000 – 1.740.000 = 33.260.000
Ví dụ 2: Cư trú – Không HĐLĐ/<3 tháng (khấu trừ 10%)
Giả định thông tin:
- C3 – Gross: 12.000.000
- M3 – Loại: Không HĐLĐ/<3m (cư trú)
(Các miễn/giảm trừ không áp dụng vào công thức khấu trừ 10% theo lần chi trả)
Tính:
Tính thuế 10% ở ô O3:
O3 = ROUND(0.1 * C3, 0) => Kết quả ra: = 1.200.000
Vì M3 là Không HĐLĐ/<3m (cư trú) nên Q3 = O3 = 1.200.000.
R3 = C3 – Q3 = 12.000.000 – 1.200.000 = 10.800.000
Lưu ý thực tế:
- Nếu tổng chi trả ≥ 2 triệu/lần, đơn vị chi trả khấu trừ 10% trước khi trả.
- Có thể không khấu trừ nếu người nhận đáp ứng điều kiện và nộp cam kết theo mẫu quy định; cuối năm vẫn tự quyết toán theo thực tế.
Ví dụ 3: Không cư trú (thuế suất 20%)
Giả định thông tin:
- C4 – Gross: 70.000.000
- D4–F4 – Miễn: 0 → G4 = Gross
- M4 – Loại: Không cư trú
Tính:
Tính thu nhập chịu thuế ở G4:
G4 = MAX(0, C4 - SUM(D4:F4)) = 70.000.000
Giải thích: Không cư trú không có giảm trừ gia cảnh, nên không dùng H–J; các khoản BH/từ thiện… nếu đáp ứng điều kiện luật có thể trừ vào G4 trước khi nhân thuế suất).
Tính thuế 20% ở P4:
P4 = ROUND(0.2 * G4, 0) = 14.000.000
Tính thuế phải nộp ở Q4:
Vì M4 là Không cư trú nên Q4 = P4 = 14.000.000.
Mức lương thực nhận:
R4 = C4 – Q4 = 70.000.000 – 14.000.000 = 56.000.000
5. Gợi ý tùy chỉnh file Excel tính thuế TNCN
File tính thuế TNCN với công thức áp dụng sẵn ở trên có thể tùy chỉnh theo mục đích và mong muốn của mỗi bạn. Dưới đây mình có gợi ý sẵn 1 số tùy chỉnh phổ biến:
TH1: Muốn đổi mức giảm trừ gia cảnh vì chính sách thay đổi => Chỉnh trực tiếp tại H (bản thân) và J (mỗi NPT) trong sheet Input.
TH2: Nếu muốn tính thuế TNCN theo năm thì làm thế nào? => Tạo pivot/tổng hợp TNTT theo 12 tháng/người; áp dụng bậc thuế năm (tách 1 sheet bậc năm) với cùng công thức rút gọn (Rate & QuickDeduction theo năm).
TH3: Có thể tách riêng BHXH/BHYT/BHTN không? => Có. Thêm các cột riêng rồi cộng vào K (khoản được trừ) hoặc tính Net sau thuế chi tiết hơn.
Trên đây là công thức tính thuế TNCN với File mẫu sẵn để có thể áp dụng được luôn. Chúc các bạn áp dụng thành công!
