Với kế toán khách sạn, sẽ phải tính tiền ở khách sạn của nhân viên/khách hàng. Trong đó ghi lại số ngày đến, ngày đi để trả phòng, từ đó tính số tiền. Đôi lúc sẽ phức tạp hơn khi giá phòng các loại phòng khác nhau, giá ở cuối tuần khác, giá ở ngày lễ khác? Vậy làm thế nào để tính số ngày ở khách sạn? Xem hướng dẫn chi tiết dưới đây:
1. Tính số ngày ở khách sạn đơn giản
1.1. Cách tính theo số tuần ở
Để tính số tuần ở khách sạn, chúng ta sử dụng hàm INT.
Áp dụng công thức INT: =INT((ngày đi -ngày đến)/7)
Từ công thức này bạn có thể tính được số tuần ở từ ngày này đến ngày khác.
Tiếp đó bạn chỉ cần kéo chuột để copy công thức đó xuống phía dưới một cách đơn giản mà không cần phải viết lại nhiều lần.
Tuy nhiên nếu tính số ngày ở khách sạn theo tuần thì không phải khách nào cũng phải ở tròn tuần mà có thể ở lẻ thêm ngày. Để tính số ngày lẻ thêm đó người dùng sử dụng hàm MOD.
Công thức như sau: =MOD((ngày đi-ngày đến),7)
Qua đó các bạn đã có thể tính được số ngày lẻ ra sau khi đã trừ đi số tuần tròn. Tương tự như phía trên, các bạn có thể copy công thức xuống phía dưới bằng cách kéo chuột xuống phía dưới.
Sau khi áp dụng công thức chúng ta đã tính được số tuần ở và số ngày ở khách sạn. Tiếp theo bạn chỉ cần tính tổng tiền dựa theo đơn giá tuần và đơn giá ngày. Bạn hãy thực hiện phép tính đơn giản này theo công thức:
Tổng tiền = số tuần ở * ĐG tuần + số ngày ở * đơn giá ngày
Sau khi áp dụng công thức trên bạn sẽ có một bảng dữ liệu như hình dưới đây. Đây chính là số tiền mà bạn phải thu từ khách hàng. Excel đã giúp bạn tính toán được số tiền một cách dễ dàng và chính xác.
1.2. Cách tính theo số ngày ở
Trong trường hợp bạn chỉ tính số ngày mà không cần tính tuần thì bạn có thể lấy số ngày đi trừ số ngày đến là được. Kết quả nhận được chính là số ngày ở khách sạn thông qua hàm trừ Excel.
Theo đó các bạn cũng có thể copy công thức xuống bên dưới một cách đơn giản là hoàn tất. Nếu muốn tính tổng tiền bạn chỉ cần lấy số ngày ở nhân với đơn giá ngày là xong. Thao tác này được thực hiện tương tự như trên.
2. Tính số ngày ở khách sạn trong các trường hợp phức tạp
Thông thường khách sạn thì chi phí sẽ chia theo các loại phòng, giá ở cuối tuần và trong tuần khác nhau, giá ngày lễ cũng khác. Dưới đây mình sẽ hướng dẫn cách tính chi tiết hơn trong các trường hợp này, giả sử ta có bảng số liệu sau:
2.1. Tính số ngày lưu trú cơ bản (bao gồm ngày nhận và trả phòng)
Trong ô E2, nhập công thức sau:
=IF(OR(B2="",C2=""),"Chưa nhập ngày",IF(C2>=B2,C2-B2+1,"Lỗi: Ngày trả phòng không hợp lệ"))
Công thức này:
- Kiểm tra xem có ô ngày nào trống không.
- Kiểm tra ngày trả phòng có hợp lệ (≥ ngày nhận phòng).
- Tính số ngày, bao gồm cả ngày đầu và cuối.
2.2. Tính số ngày làm việc (loại trừ thứ Bảy, Chủ Nhật):
Để tính số ngày ở khách sạn nhưng chỉ tính các ngày trong tuần mà không tính T7, CN ta làm như sau. Trong ô H2, nhập:
=IF(OR(B2="",C2=""),"Chưa nhập ngày",IF(C2>=B2,NETWORKDAYS(B2,C2),"Lỗi: Ngày trả phòng không hợp lệ"))
Trong công thức này sử dụng Hàm NETWORKDAYS ví nó chỉ tính các ngày từ thứ Hai đến thứ Sáu.
2.3. Tính số ngày cuối tuần ở khách sạn:
Khi giá ở khách sạn trong cuối tuần có giá khác, ta muốn tính riêng số ngày cuối tuần (chỉ tính thứ 7, chủ nhật) ở khách sạn thì ta thực hiện như sau. Trong trong ô I2 (hoặc cột mới), nhập:
=IF(OR(B2="",C2=""),"Chưa nhập ngày",IF(C2>=B2,(C2-B2+1)-NETWORKDAYS(B2,C2),"Lỗi"))
Công thức trên sử dụng lấy tổng số ngày ở trừ đi số ngày làm việc (các ngày trong tuần) để ra số ngày cuối tuần.
2.4. Tính chi phí lưu trú
Ví dụ giá các loại phòng là khác nhau, ta sẽ tạo một sheet mới (gọi là “BangGia”) để điền bảng giá phòng như sau:
Ta tính chi phí mỗi đêm như sau: Trong ô F2, sử dụng VLOOKUP để lấy giá phòng từ sheet BangGia với công thức:
=VLOOKUP(D2,BangGia!A:B,2,FALSE)
Để tính tổng chi phí, trong ô G2 ta sử dụng công thức sau:
=IF(E2="Chưa nhập ngày","",IF(E2="Lỗi: Ngày trả phòng không hợp lệ","",E2*F2))
Công thức này nhân số ngày lưu trú với chi phí mỗi đêm, chỉ tính nếu không có lỗi.
2.5. Trong trường hợp ngày ở khách sạn có ngày lễ
Nếu khách sạn không tính ngày lễ (hoặc tính giá khác), tạo một sheet “NgayLe” với danh sách ngày lễ:
Tính số ngày lễ trong khoảng lưu trú, trong ô mới (ví dụ, cột J):
=IF(OR(B2="",C2=""),"Chưa nhập ngày",IF(C2>=B2,SUMPRODUCT(--(NgayLe!A:A>=B2)*(NgayLe!A:A<=C2)),"Lỗi"))
Tính chi phí điều chỉnh theo ngày lễ, giả sử ngày lễ có giá gấp đôi, sửa công thức tổng chi phí (cột G):
=IF(E2="Chưa nhập ngày","",IF(E2="Lỗi: Ngày trả phòng không hợp lệ","",E2*F2+J2*F2))
Trên đây là các hướng dẫn chi tiết về cách tính số ngày ở khách sạn trong Excel và hướng dẫn nâng cao liên quan. Chúc các bạn áp dụng thành công!
