Cách tính tổng hàng ngang trong Excel có và không có điều kiện

Để tính tổng hàng ngang trong Excel nhanh chóng ta có thể sử dụng:

• Hàm SUM với cú pháp: =SUM(phạm vi ô) ví dụ như tính tổng hàng ngang từ A3 đế F3 thì sử dụng =SUM(A3:F3)
• Sử dụng tính năng AutoSum: Chọn ô bên phải dữ liệu cần tính tổng => vào home => trong nhóm Edit chọn biểu tượng AutoSum (biểu tượng chữ Sigma, Σ) => kiếm tra vùng dữ liệu, nếu đúng ấn Enter (tính năng AutoSum cũng có thể sử dụng bằng phím tắt Alt + = )

Trong bài viết dưới đây, Kế Toán VN sẽ hướng dẫn bạn cách tính tổng theo hàng ngang trong Excel với các trường hợp phức tạp hơn khi có điều kiện với các ví dụ thực tế.

Tải ngay file công thức mẫu tính tổng theo hàng ngang trong Excel

1. Sử dụng hàm SUM để tính tổng theo hàng ngang

Khi tính tổng hàng ngang trong Excel mà không có điều kiện thì cách đơn giản nhất là sử dụng hàm SUM với cú pháp hàm:

=SUM(number1,[number2],…)

Trong đó:

• number1: đối số bắt buộc, là số đầu tiên bạn muốn thêm vào. Số đó có thể là 4, tham chiếu ô như B6, hoặc ô phạm vi như B2:B8.
• number2-255: đối số tùy chọn, là số thứ 2 đến thứ 255 mà bạn muốn cộng. Số đó có thể là 4, tham chiếu ô như B6, hoặc ô phạm vi như B2:B8.

Áp dụng cấu trúc hàm như trên, ta có công thức tính tổng theo hàng ngang như sau:

=SUM(C2:E2)

Sao chép công thức cho tất cả ô của cột ta sẽ thu được kết quả:

Hoặc các bạn cũng có thể dụng công thức SUM như sau để tính tổng:

=SUM(C2;D2;E2)

Sao chép công thức cho tất cả ô ta sẽ thu được kết quả:

2. Sử dụng tính năng AutoSum để tính tổng hàng ngang

Cách đơn giản thứ 2 khi tính tổng không có điều kiện trong Excel là ta sử dụng tính năng AutoSum:

Cách 1: Sử dụng phím tắt Alt + =

Để con trỏ chuột tại vị trí cần tính tổng rồi nhấn tổ hợp phím tắt Alt + = (tính năng AutoSum sẽ được kích hoạt) như sau:

Nếu tính tổng cho nhiều hàng một lúc thì chỉ cần bôi đen những ô cần tính rồi nhấn Alt + = là được. Kết quả là hàm SUM sẽ được áp dụng cho tất cả các ô được bôi đen.

Cách 2: Sử dụng tính năng AutoSum trên thẻ home

Ta đặt con trỏ chuột ở vị trí cần tính tổng rồi chọn thẻ Home => AutoSum. Nếu muốn tính tổng nhiều ô một lúc thì các bạn bôi đen những ô đó rồi chọn AutoSum

3. Tính tổng hàng ngang theo 1 điều kiện (áp ngay trên giá trị của hàng)

Trong trường hợp muốn cộng tổng các giá trị theo hàng ngang trong Excel với điều kiện có giá trị nào đó thì ta sẽ sử dụng hàm SUMIF với cú pháp như sau:

=SUMIF(range, criteria)

Trong đó:

• range là phạm vi dữ liệu.
• criteria là điều kiện.

Ví dụ với dữ liệu về bảng điểm như sau:

Giờ ta muốn tính tổng điểm của từng người từ Q1 đến Q4 nhưng với điều kiện là chỉ lấy giá trị >= 8 thì ta sẽ sử dụng công thức hàm SUMIF như sau:

=SUMIF(B2:E2,">=8")

Trong công thức trên Excel sẽ chỉ cộng những ô trong B2:E2 thỏa >=8 và kết quả như sau:

Ta cũng có thể sử dụng các biến thể cho các trường hợp thường gặp như:

• Chỉ tính tổng số dương: =SUMIF(B2:E2,">0")
• Chỉ tính tổng số âm: =SUMIF(B2:E2,"<0")

4. Tính tổng hàng ngang theo nhãn cột/tiêu đề (điều kiện theo header)

Ví dụ ta có một hàng tiêu đề như sau: Doanh thu | Chi phí | Doanh thu | Chi phí và ta cần cộng tổng tất cả giá trị theo hàng ngang và được đánh dấu tiêu đề là doanh thu ta sử dụng hàm SUMIF với công thức sau:

=SUMIF(criteria_range, criteria, sum_range)

Trong đó:

• criteria_range là vùng điều kiện.
• criteria là điều kiện.
• sum_range là vùng tính tổng.

Ví dụ với bảng dữ liệu về doanh thu và chi phí như sau:

Giờ ta muốn tính tổng doanh thu của từng người thì sẽ sử dụng hàm SUMIF như sau:

=SUMIF($B$1:$E$1,"Doanh thu",B2:E2)

Ngoài ra, ta có thể mở rộng điều kiện bằng cách sử dụng ký tự đại diện như sau:

• Tính tổng hàng ngang mọi cột miễn là bắt đầu bằng “Doanh thu”: =SUMIF($B$1:$E$1,"Doanh thu*",B2:E2)
• Tỉnh tổng hàng ngang mọi cột miễn là có chứa chữ “thu”: =SUMIF($B$1:$E$1,"*thu*",B2:E2)

Lưu ý rằng: criteria_range và sum_range phải có cùng số cột (bằng nhau về chiều ngang)

5. Tính tổng hàng ngang theo nhiều điều kiện

Với các tính huống muốn tính tổng giá trị theo hàng ngang trong Excel nhưng có nhiều điều kiện thì ta sẽ sử dụng hàm SUMIFS với cú pháp sau:

=SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)

Trong đó:

• sum_range là vùng cần cộng theo hàng ngang.
• riteria_range1 và criteria1 lần lượt là vùng điều kiện và điều kiện 1.
• criteria_range2 + criteria2 lần lượt là vùng điều kiện và điều kiện 2.

Vẫn lấy ví dụ về bảng dữ liệu doanh thu và chi phí ở trên như sau:

Giả sử giờ ta muốn tính tổng doanh thu của Bình với giá trị lớn hơn 100 thì ta sử dụng hàm SUMIFS như sau:

=SUMIFS(B4:E4,$B$1:$E$1,"Doanh thu",B4:E4,">=100")

6. Tính tổng hàng ngang theo tập cột tùy chọn (ví dụ theo quý/tháng)

Trong trường hợp ta muốn tính tổng hàng ngang của một tập nào đó, ví dụ như tính tổng doanh thu theo quý, theo các tháng thì ta có thể sử dụng cách kết hợp hàm như sau:

Ví dụ dữ liệu mẫu về doanh thu theo 12 tháng như sau:

Giả sử giờ ta muốn tính tổng doanh thu của từng người theo các quý 1, quý 2, quý 3 và quý 4 thì ta sẽ sử dụng như sau:

Cách 1: Sử dụng kết hợp hàm SUMPRODUCT và hàm MATCH

Ví dụ để tính doanh thu quý 1 ta sử dụng công thức sau:

=SUMPRODUCT(ISNUMBER(MATCH(B$1:M$1,{"Th1","Th2","Th3"},0)) * B2:M2)

Trong đó:

• MATCH(B$1:M$1,{"Th1","Th2","Th3"},0) trả về vị trí nếu tiêu đề là Th1/Th2/Th3, còn lại #N/A. 
• ISNUMBER(...) biến thành mảng 1/0 (1 khi là tháng thuộc Quý I). 
• Nhân với B2:M2 để lọc giá trị theo tháng đã chọn, rồi cộng tổng.

Sau đó ta làm tương tự cho Q2, Q3, Q4 để có kết quả như sau:

Cách 2: Sử dụng hàm SUM kết hợp với hàm FILTER

Với các phiên bản Excel 365 trở lên thì ta sẽ sử dụng hàm SUM kết hợp với FILTER, ví dụ vẫn tính tổng doanh thu theo quý của từng người như trên thì ta sẽ sử dụng công thức sau:

=SUM( FILTER(B2:M2, ISNUMBER(MATCH(B$1:M$1,{"Th1","Th2","Th3"},0))) )

Trong đó, hàm FILTER lấy các giá trị trên hàng tương ứng với tháng thuộc Quý I, rồi SUM

7. Tính tổng hàng ngang theo điều kiện năm hoặc khoảng thời gian

Trong trường hợp muốn có bảng dữ liệu theo thời gian thì ta sẽ phát sinh nhu cầu muốn tính tổng theo hàng ngang với điều kiện thỏa mãn điều kiện năm (ví dụ: năm 2024) hoặc theo khoảng thời gian (ví dụ từ 30/06 đến 30/07). Ví dụ với bảng dữ liệu doanh thu ghi nhận theo ngày như sau:

Ví dụ muốn tính tổng doanh thu của mọi người chỉ tính năm 2024 ta sử dụng công thức hàm SUMPRODUCT như sau:

=SUMPRODUCT( (YEAR(B$1:M$1)=2024) * B2:M2 )

Kết quả trả về như sau:

Trong trường hợp muốn tính tổng theo điều kiện một khoảng thời gian ví dụ như trong quý 2 (tức là từ tháng 4 đến hết tháng 6) thì ta sử dụng công thức hàm SUMPRODUCT như sau:

=SUMPRODUCT((B$1:M$1>=DATE(2024,4,1)) *(B$1:M$1<=DATE(2024,6,30)) *B2:M2)

Kết quả trả về:

Lưu ý: Hàng điều kiện ngày phải là ngày đúng kiểu Date (không phải text). Nếu đang là text “2024-01-01”, hãy chọn dải dữ liệu→ Data → Text to Columns → Finish (Excel sẽ nhận dạng ngày).

8. Cộng tổng hàng ngang trong Excel với điều kiện theo trạng thái nằm ở Header

Trong nhiều bảng dữ liệu, ta sẽ thêm cột note ghi chú trạng thái nằm ở header. Khi muốn cộng tổng theo hàng ngang với điều kiện cụ thể theo trạng thái. Ví dụ với bảng dữ liệu doanh thu có ghi chú trạng thái thanh toán như sau:

Giả sử ta muốn tính tổng giá trị doanh thu của từng người theo hàng ngang với điều kiện ghi chú “Đã TT” thì ta sử dụng hàm SUMIF như sau:

=SUMIF($B$1:$E$1,"Đã TT",B2:E2)

Trong trường hợp header mà lẫn lộn cả khoảng trắng thì ta dùng hàm TRIM trong hàm SUMPRODUCT như sau:

=SUMPRODUCT( (TRIM($B$1:$E$1)="Đã TT") * B2:E2 )

Như vậy, bài viết trên đã hướng dẫn các bạn những cách tính tổng theo hàng ngang trong Excel. Hy vọng bài viết sẽ hữu ích với các bạn trong quá trình làm việc. Chúc các bạn thành công!